InstallingFedoraGSearch: demoFoxmlToSolr.xslt

<?xml version="1.0" encoding="UTF-8"?> 
<!-- $Id: demoFoxmlToLucene.xslt 5734 2006-11-28 11:20:15Z gertsp $ -->
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"   
    xmlns:exts="xalan://dk.defxws.fedoragsearch.server.GenericOperationsImpl"
    exclude-result-prefixes="exts"
    xmlns:zs="http://www.loc.gov/zing/srw/"
    xmlns:foxml="info:fedora/fedora-system:def/foxml#"
    xmlns:dc="http://purl.org/dc/elements/1.1/"
    xmlns:oai_dc="http://www.openarchives.org/OAI/2.0/oai_dc/"
    xmlns:uvalibdesc="http://dl.lib.virginia.edu/bin/dtd/descmeta/descmeta.dtd"
    xmlns:uvalibadmin="http://dl.lib.virginia.edu/bin/admin/admin.dtd/"
    xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
    <xsl:output method="xml" indent="yes" encoding="UTF-8"/>
    
    <!--
        This xslt stylesheet generates the Solr doc element consisting of field elements
        from a FOXML record. The PID field is mandatory.
        Options for tailoring:
        - generation of fields from other XML metadata streams than DC
        - generation of fields from other datastream types than XML
        - from datastream by ID, text fetched, if mimetype can be handled
        currently the mimetypes text/plain, text/xml, text/html, application/pdf can be handled.
    -->
    
    <xsl:param name="REPOSITORYNAME" select="repositoryName"/>
    <xsl:param name="FEDORASOAP" select="repositoryName"/>
    <xsl:param name="FEDORAUSER" select="repositoryName"/>
    <xsl:param name="FEDORAPASS" select="repositoryName"/>
    <xsl:param name="TRUSTSTOREPATH" select="repositoryName"/>
    <xsl:param name="TRUSTSTOREPASS" select="repositoryName"/>
    <xsl:variable name="PID" select="/foxml:digitalObject/@PID"/>
    <xsl:variable name="docBoost" select="1.4*2.5"/> <!-- or any other calculation, default boost is 1.0 -->
    
    <xsl:template match="/">
        <add> 
            <doc> 
                <xsl:attribute name="boost">
                    <xsl:value-of select="$docBoost"/>
                </xsl:attribute>
                <!-- The following allows only active demo FedoraObjects to be indexed. -->
                    <xsl:if test="foxml:digitalObject/foxml:objectProperties/foxml:property[@NAME='http://www.w3.org/1999/02/22-rdf-syntax-ns#type' and @VALUE='FedoraObject']">
                            <xsl:apply-templates mode="activeDemoFedoraObject"/>
                    </xsl:if>
            </doc>
        </add>
    </xsl:template>
    
    <xsl:template match="/foxml:digitalObject" mode="activeDemoFedoraObject">
        <field name="PID" boost="2.5">
            <xsl:value-of select="$PID"/>
        </field>
        <xsl:for-each select="foxml:objectProperties/foxml:property">
            <field >
                <xsl:attribute name="name"> 
                    <xsl:value-of select="concat('fgs.', substring-after(@NAME,'#'))"/>
                </xsl:attribute>
                <xsl:value-of select="@VALUE"/>
            </field>
        </xsl:for-each>
        <xsl:for-each select="foxml:datastream/foxml:datastreamVersion[last()]/foxml:xmlContent/oai_dc:dc/*">
            <field >
                <xsl:attribute name="name">
                    <xsl:value-of select="concat('dc.', substring-after(name(),':'))"/>
                </xsl:attribute>
                <xsl:value-of select="text()"/>
            </field>
        </xsl:for-each>

        <xsl:for-each select="foxml:datastream/foxml:datastreamVersion[last()]/foxml:xmlContent/dc:dc/*">
            <field >
                <xsl:attribute name="name">
                    <xsl:value-of select="concat('dc.', substring-after(name(),':'))"/>
                </xsl:attribute>
                <xsl:value-of select="text()"/>
            </field>
        </xsl:for-each>

        <xsl:for-each select="foxml:datastream[@ID='RELS-EXT']/foxml:datastreamVersion[last()]/foxml:xmlContent/rdf:RDF/rdf:Description/*">
            <field >
                <xsl:attribute name="name">
                   <xsl:value-of select="concat('rdf.', translate(name(), ':', '.'))"/>
                </xsl:attribute>
                <xsl:value-of select="substring-after(@rdf:resource, 'info:fedora/')"/>
                <xsl:value-of select="text()"/>
            </field>
        </xsl:for-each>
        
        <!-- a managed datastream is fetched, if its mimetype 
            can be handled, the text becomes the value of the field. -->
        <xsl:for-each select="foxml:datastream[@CONTROL_GROUP='M']">
            <field index="TOKENIZED" store="YES" termVector="NO">
                <xsl:attribute name="name">
                    <xsl:value-of select="concat('dsm.', @ID)"/>
                </xsl:attribute>
                <xsl:value-of select="exts:getDatastreamText($PID, $REPOSITORYNAME, @ID, $FEDORASOAP, $FEDORAUSER, $FEDORAPASS, $TRUSTSTOREPATH, $TRUSTSTOREPASS)"/>
            </field>
        </xsl:for-each>
        
    </xsl:template>
    
</xsl:stylesheet>